Use automake for portmixer.

lib-src/portmixer/Makefile.am

@@ -0,0 +1,9 @@
+ACLOCAL_AMFLAGS = -I m4
+
+SUBDIRS = px_tests src
+
+dist_doc_DATA = LICENSE.txt README.txt
+
+include_HEADERS = include/portmixer.h
+
+EXTRA_DIST = portaudio.patch

lib-src/portmixer/configure.ac

@@ -2,19 +2,23 @@
 # PortMixer 2.0
 #
 
-AC_INIT(PortMixer, 2.0, audacity.sourceforge.net, portmixer)
+AC_PREREQ([2.60])
+AC_INIT([PortMixer], [2.0], [audacity.sourceforge.net], [portmixer])
+AC_CONFIG_AUX_DIR([autotools])
+AC_CONFIG_MACRO_DIR([m4])
 AC_CONFIG_SRCDIR(src)
-AC_CONFIG_FILES([Makefile])
+
+AM_INIT_AUTOMAKE([1.11 dist-xz foreign no-dist-gzip -Wall])
+AM_MAINTAINER_MODE([disable])
 
 #
 # Checks for programs.
 #
 AC_PROG_CC
-AC_PROG_RANLIB
-AC_PATH_PROG(AR, ar, no)
-if [[ $AR = "no" ]] ; then
-    AC_MSG_ERROR([Could not find ar - needed to create a library]);
-fi
+AM_PROG_CC_C_O
+AM_PROG_AR
+
+LT_INIT
 
 #
 # Checks for libraries.
@@ -44,9 +48,9 @@ AC_ARG_WITH([pa-include],
 #
 #
 if test -n "$with_portaudio"; then
-   CPPFLAGS="$CPPFLAGS -I$withval"
-   AC_SUBST(cflags, ["$cflags -I$withval"] )
+   PORTAUDIO_CFLAGS="-I$withval"
 fi
+AC_SUBST(PORTAUDIO_CFLAGS)
 
 #
 # Check which APIs are available
@@ -115,35 +119,29 @@ if [[ $have_portaudio = "yes" ]] ; then
    fi
 fi
 
-#
-#
-#
-AC_SUBST( include, [-Iinclude] )
-AC_SUBST( objects, [px_mixer.o] )
-
 #
 # Set up to use the identified ones
 #
 have_support=no
 AC_MSG_NOTICE([---------------------------------------])
+AM_CONDITIONAL([USE_UNIX_OSS], [test "$have_oss" = yes])
 if [[ $have_oss = "yes" ]] ; then
    AC_MSG_NOTICE([Including support for OSS]);
    AC_DEFINE(PX_USE_UNIX_OSS)
-   objects="$objects px_unix_oss.o"
    have_support=yes
 fi
 
+AM_CONDITIONAL([USE_LINUX_ALSA], [test "$have_alsa" = yes])
 if [[ $have_alsa = "yes" ]] ; then
    AC_MSG_NOTICE([Including support for ALSA])
    AC_DEFINE(PX_USE_LINUX_ALSA)
-   objects="$objects px_linux_alsa.o"
    have_support=yes
 fi
 
+AM_CONDITIONAL([USE_MAC_COREAUDIO], [test "$have_coreaudio" = yes])
 if [[ $have_coreaudio = "yes" ]] ; then
    AC_MSG_NOTICE([Including support for Coreaudio])
    AC_DEFINE(PX_USE_MAC_COREAUDIO)
-   objects="$objects px_mac_coreaudio.o"
    have_support=yes
 fi
 
@@ -152,6 +150,8 @@ if [[ $have_support = "no" ]] ; then
 fi
 AC_MSG_NOTICE([---------------------------------------])
 
+AC_CONFIG_FILES([Makefile px_tests/Makefile src/Makefile])
+
 #
 # Write it all out
 #

lib-src/portmixer/px_tests/Makefile.am

@@ -0,0 +1,5 @@
+check_PROGRAMS = px_test
+
+px_test_CPPFLAGS = -I$(top_srcdir)/include
+px_test_LDADD = $(top_builddir)/src/libportmixer.la
+px_test_SOURCES = px_test.c

lib-src/portmixer/src/Makefile.am

@@ -0,0 +1,30 @@
+lib_LTLIBRARIES = libportmixer.la
+
+libportmixer_la_CPPFLAGS = -I$(top_srcdir)/include $(PORTAUDIO_CFLAGS)
+libportmixer_la_SOURCES = \
+	px_mixer.c \
+	px_mixer.h \
+	$(NULL)
+
+if USE_UNIX_OSS
+libportmixer_la_SOURCES += px_unix_oss.c
+endif
+
+if USE_LINUX_ALSA
+libportmixer_la_SOURCES += px_linux_alsa.c
+endif
+
+if USE_MAC_COREAUDIO
+libportmixer_la_SOURCES += px_mac_coreaudio.c
+endif
+
+EXTRA_DIST = \
+	px_example_api.c \
+	px_win_common.c \
+	px_win_common.h \
+	px_win_ds.c \
+	px_win_endpoint.c \
+	px_win_endpoint.h \
+	px_win_wasapi.c \
+	px_win_wmme.c \
+	$(NULL)